When I am programming, I want to view recordsets that I've created on
the fly. I open them with something like:

set tTable = CurrentDb.OpenRecordSet("select fRecNo,fDesc from
tDrivers")

If I executed this line, and interupted the program, what is the
fastest way to view the resulting recordset to make sure things look
all right?

David

David wrote:
dumprs ttable

Sub dumpRs(rs As Recordset)
Dim cBook As String
If rs.RecordCount = 0 Then
Debug.Print "empty."
Else
cBook = rs.Bookmark
rs.MoveFirst
dumpRecord rs, True
Do Until rs.EOF
dumpRecord rs
rs.MoveNext
Loop
Debug.Print
rs.Bookmark = cBook
End If
End Sub

Sub dumpRecord(rs As Recordset, Optional fieldnames = False)
Dim fd As Field
For Each fd In rs.Fields
If fd.OrdinalPosition > 0 Then Debug.Print ", ";
If fieldnames Then
Debug.Print fd.Name;
Else
Debug.Print fd.Value;
End If
Next
Debug.Print
End Sub



--
Bas Cost Budde, Holland
http://www.heuveltop.nl/BasCB/msac_index.html
I prefer human mail above automated so in my address
replace the queue with a tea

David wrote:

Define the sql with a string variable and do a debug.print on the string
before executing the above. Cut the statement from the debug window,
paste into an SQL view of a query and voila!

Sounds involved, but I do this all the time and it works fine.

--
Tim http://www.ucs.mun.ca/~tmarshal/
^o<
/#) "Burp-beep, burp-beep, burp-beep?" - Quaker Jake
/^^ "What's UP, Dittoooooo?" - Ditto

Tim Marshall wrote:
I do that all the time too, and I find it so boring that I wrote a small
helper routine:

Sub Q(Optional cSQL = "")
Dim qd As QueryDef
On Error Resume Next
DoCmd.Close acQuery, "_temp", acSaveNo
Set qd = CurrentDb.QueryDefs("_temp")
qd.SQL = cSQL
DoCmd.OpenQuery qd.Name, acViewDesign
End Sub

I have a query called _temp for this purpose. Now, from the debug
window, I can type

q <variable>

and I will get the query in design view. More Voila!


--
Bas Cost Budde, Holland
http://www.heuveltop.nl/BasCB/msac_index.html
I prefer human mail above automated so in my address
replace the queue with a tea

David wrote:
'here is a way to pass a SQL string to a proc to display the results.
'the ShowResults sub calls DisplayResults and presents the data in
datasheet view. If JunkQuery exists, it gets deleted. A new query is
then created called JunkQuery. The result records are displayed.

Sub ShowResults()
DisplayResults "Select * From Table"
End Sub

Sub DisplayResults(strSQL As String)

Dim dbs As Database
Dim qdfNew As QueryDef

Set dbs = CurrentDb

On Error Resume Next
DoCmd.DeleteObject acQuery, "JunkQuery"

Set qdfNew = dbs.CreateQueryDef("JunkQuery", strSQL)

DoCmd.OpenQuery "JunkQuery"

End Sub

Aha, you too ;-)

--
Bas Cost Budde, Holland
http://www.heuveltop.nl/BasCB/msac_index.html
I prefer human mail above automated so in my address
replace the queue with a tea

Bas Cost Budde wrote:
Great minds think alike. :-)